Question 72

Comment vérifier l'existence d'une clé dans la base de registre ?

La meilleure solution consiste à essayer d'ouvrir la clé dont on veut vérifier l'existence. Si l'ouverture réussit, alors c'est que la clé existe. Si l'ouverture échoue, alors on récupère l'erreur, ce qui nous permettra de savoir si l'échec de l'ouverture est dû à la non-existence de la clé.

Voici le code de la fonction RegKeyExists qui permet de vérifier l'existence d'une clé dans la base de registre en utilisant ce principe. Le code est à placer dans un module :

' Déclaration des API
Public Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long
Public Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long

' Constantes d'erreurs
Public Const ERROR_FILE_NOT_FOUND = 2&
Public Const ERROR_SUCCESS = 0&

' Enumération des clés "racines"
Public Enum RegRootKey
    HKEY_CLASSES_ROOT = &H80000000
    HKEY_CURRENT_CONFIG = &H80000005
    HKEY_CURRENT_USER = &H80000001
    HKEY_DYN_DATA = &H80000006
    HKEY_LOCAL_MACHINE = &H80000002
    HKEY_PERFORMANCE_DATA = &H80000004
    HKEY_USERS = &H80000003
End Enum

' Les différents types d'accès possibles
Public Const STANDARD_RIGHTS_ALL = &H1F0000
Public Const SYNCHRONIZE = &H100000
Public Const READ_CONTROL = &H20000
Public Const STANDARD_RIGHTS_READ = (READ_CONTROL)
Public Const STANDARD_RIGHTS_WRITE = (READ_CONTROL)
Public Const KEY_CREATE_LINK = &H20
Public Const KEY_CREATE_SUB_KEY = &H4
Public Const KEY_ENUMERATE_SUB_KEYS = &H8
Public Const KEY_NOTIFY = &H10
Public Const KEY_QUERY_VALUE = &H1
Public Const KEY_SET_VALUE = &H2
Public Const KEY_READ = ((STANDARD_RIGHTS_READ Or KEY_QUERY_VALUE Or KEY_ENUMERATE_SUB_KEYS Or KEY_NOTIFY) And (Not SYNCHRONIZE))
Public Const KEY_WRITE = ((STANDARD_RIGHTS_WRITE Or KEY_SET_VALUE Or KEY_CREATE_SUB_KEY) And (Not SYNCHRONIZE))
Public Const KEY_EXECUTE = (KEY_READ)
Public Const KEY_ALL_ACCESS = ((STANDARD_RIGHTS_ALL Or KEY_QUERY_VALUE Or KEY_SET_VALUE Or KEY_CREATE_SUB_KEY Or KEY_ENUMERATE_SUB_KEYS Or KEY_NOTIFY Or KEY_CREATE_LINK) And (Not SYNCHRONIZE))

Public Function RegKeyExists(RootKey As RegRootKey, SubKey As String) As Boolean

    Dim RC As Long ' Code retour des API
    Dim hKey As Long ' handle de la clé ouverte

    ' Ouvre la clé
    RC = RegOpenKeyEx(RootKey, SubKey, ByVal 0&, KEY_READ, hKey)
    If RC = ERROR_SUCCESS Then
        RegKeyExists = True
        Call RegCloseKey(hKey)
    ElseIf RC = ERROR_FILE_NOT_FOUND Then
        RegKeyExists = False
    Else
        MsgBox "Erreur inattendue.", vbExclamation
    End If

End Function

Sub Main()

    If RegKeyExists(HKEY_CURRENT_USER, "Software\Microsoft\Internet Explorer\Main") = True Then
        MsgBox "La clé existe.", vbInformation
    Else
        MsgBox "La clé n'existe pas.", vbInformation
    End If

End Sub